qrp_report

****************************************************************************************************

*                                           PROGRAM OVERVIEW

****************************************************************************************************

*

* PROGRAM: attrition_output.sas  

* Created (mm/dd/yyyy): 05/18/2021

*

*--------------------------------------------------------------------------------------------------

* PURPOSE: This macro outputs patient and/or episode level attrition data

*                                        

*  Program inputs:                                                                                   

*   - agg_patient_attrition

*   - agg_episode_attrition

* 

*  Program outputs: 

* 

*   -repdata.table&tablenum.&tableletter.

* 

*  PARAMETERS:

*   -tabletype - patient - Output patient level attrition table

*              - episode - Output episode level attrition table                                                                     

*            

*  Programming Notes:         

*                                                                           

*

*--------------------------------------------------------------------------------------------------

* CONTACT INFO: 

*  Sentinel Coordinating Center

*  info@sentinelsystem.org

*

***************************************************************************************************;

​

%macro attrition_output(tabletype=);

​

    %if &&attrition_&tabletype > 0 %then %do;

    %tableletter();

​

        /*assign footnotes*/

        %let num_fn = 0;

        %let exclincl = N;

        %let milexcl = N;

        %let claim_level_descr = &tabletype.;

        data repdata.table&tablenum.&tableletter.;

            set agg_&tabletype._attrition&attrperiodid;

            if index(lowcase(report_descr), 'evidence of')>0 then do;

                call symputx('num_fn', 1);

                if claim_level = 'MIL' then call symputx('milexcl', 'Y'); /*to mark which row to apply superscript*/

                if claim_level ne 'MIL' then call symputx('exclincl', 'Y');

                %if %index(&reporttype,T4) %then %do; call symputx('claim_level_descr', 'Pregnancy episodes'); %end;

                %else %if &tabletype = episode %then %do; call symputx('claim_level_descr', 'Episodes'); %end;

                %else %if &tabletype = patient %then %do; call symputx('claim_level_descr', 'Patients'); %end;

            end;

            %if %index(&reporttype,T2L2) %then %do;

            length monitoringperiod 3;

            monitoringperiod=&j;

            %end;

            %if %index(&customizecolumns., redactevents)>0 and 

                %sysfunc(prxmatch(m/T2L2|T4L2/i,&reporttype.)) > 0 %then %do;

            if index(lowcase(report_descr), 'event')>0 then delete;

            %end;

        run;

​

        %if %eval(&num_fn.>0) %then %do;

            data _footnotes;

               length footnote_order 3; 

               set lookup.lookup_footnotes (where = (type = "attrition"));

               by order;

               footnote_order = _n_;

            run;

​

            proc sql noprint;

              select description into: fn1 - :fn&num_fn.

              from _footnotes

              order by order;

            quit;

​

            /* Assign macro variables for superscipts */

            %assign_superscripts(type =exclincl, order = 1);

        %end;

​

        %if &destination = excel %then %do;

        ods excel options(sheet_name="Table &tablenum.&tableletter." tab_color="teal" flow="tables");

        %end;

        ods proclabel = "Table &tablenum.&tableletter.";

        proc report data=repdata.table&tablenum.&tableletter. nofs nowd spanrows missing

            style(header)=[rules=none frame=void vjust=b borderbottomcolor=bgr bordertopcolor=bgr background=bgr borderleftcolor=bgr] split='*'

            style(report)=[rules=none frame=void cellpadding=1.75pt];

            column report_descr (headerlabel,(grouplabel,(agg_remaining_char agg_excluded_char))) dummyvar;

            define report_descr / group order=data ' ' style(column)=[just=L] 

                                                       style(header)=[background = bgr borderleftcolor= bgr borderrightcolor=bgr];

            define headerlabel / nozero across order=data ' ' style(header)=[rules=none vjust=b borderbottomcolor=black background=bgr borderrightcolor=black