qrp_report

****************************************************************************************************

*                                           PROGRAM OVERVIEW

****************************************************************************************************

*

* PROGRAM: figure_t5_output.sas  

* Created (mm/dd/yyyy): 09/08/2021

*

*--------------------------------------------------------------------------------------------------

* PURPOSE: Produce type 5 figures F1-F3

*

*  Program inputs:                                                                                   

*   - figure123.sas7bdat

* 

*  Program outputs:                                                                                                                           

*   - N/A

* 

*  PARAMETERS: 

*   -figure: figure

*   -figurenum: figure number for report

*   -figureletter: figure letter for report

*   -title: figure title

*   -where: where clause to restrict figure123.sas7bdat

*   -figuresub: row in figurefile to produce table

*   -yaxislabel1: Label for primary Y axis

*   -yaxislabel2: Label for secondary Y axis

*   -yvar: variable to use in plot

* 

*  Programming Notes:                                                                                

*

*

*--------------------------------------------------------------------------------------------------

* CONTACT INFO: 

*  Sentinel Coordinating Center

*  info@sentinelsystem.org

*

***************************************************************************************************;

​

%macro figure_t5_output(figure=, figurenum=, figureletter=, title=, where=, figuresub=, yaxislabel1=, yaxislabel2=, yvar=);

​

    %put =====> MACRO CALLED: figure_t5_output;

​

    /*figuresub format to display formatted values in figure*/

    %if &figuresub. ne overall %then %do;

        %let t5figureformat = $&figuresub.fmt.; 

    %end;

​

    /*footnotes*/

    %if &collapse_vars = race & &figuresub. = race %then %do;

        data _footnotes;

            length footnote_order 3; 

            set lookup.lookup_footnotes(where = (type = "t5tablefig"));

            by order;

            footnote_order = _n_;

            call symputx('num_fn', 1);

        run;

​

        proc sql noprint;

            select description into: fn1 - :fn&num_fn.

            from _footnotes

            order by order;

        quit;

​

        %assign_superscripts(type=raceunknown, order = 2);

        %let unicode_forplot = %scan(&unicode_list., 1);

​

        /*modify format*/

        proc format;

        value $racefmtsuper

        "0"   = "Unknown(*ESC*){unicode '&unicode_forplot'x}"

        "1"   = "American Indian or Alaska Native"

        "2"   = "Asian"

        "3"   = "Black or African American"

        "4"   = "Native Hawaiian or Other Pacific Islander"

        "5"   = "White"

        "M"   = "Multi-racial";

        run;

        %let t5figureformat = $racefmtsuper.;

    %end;

​

    /*Save dataset to REPORTDATA folder*/

    %isdata(dataset=repdata.figure&figurenum.&figureletter.);

    %if %eval(&nobs.<1) %then %do;

        data repdata.figure&figurenum.&figureletter.;

            set figure123(where=(&where.));

        run;

    %end;

​

    /*stratified plot - collapse strata to determine correct Y axis*/

    %let axisdata = repdata.figure&figurenum.&figureletter.;

    %if &figuresub. ne overall %then %do;

        proc sql noprint;