qa_package_pd

/*-------------------------------------------------------------------------------------*\

|  PROGRAM NAME:                                                                        |

|     scdm_data_qa_review-level1.sas                                                    |

|                                                                                       |

|---------------------------------------------------------------------------------------|

|  PURPOSE:                                                                             |

|     The purpose of this program is to perform Level 1 data checks on all SCDM         |

|     tables.                                                                           |

|---------------------------------------------------------------------------------------|

|  PROGRAM INPUT:                                                                       |

|     see 00.0_scdm_data_qa_review_master_file.sas                                      |

|                                                                                       |

|  PROGRAM OUTPUT:                                                                      |

|     see Workplan PDF                                                                  |

|---------------------------------------------------------------------------------------|

|  CONTACT:                                                                             |

|     Sentinel Coordinating Center                                                      |

|     info@sentinelsystem.org                                                           |

\*-------------------------------------------------------------------------------------*/

​

/*-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-;

*  PLEASE DO NOT EDIT BELOW WITHOUT CONTACTING THE SENTINEL OPERATIONS CENTER           ;

*-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-;

/**/

​

* ---------------------- Macro: l1_variable ----------------------------------------------------- ;

* Logic to confirm variables within table meet requirements existing, type, length and sort order ;

* ----------------------------------------------------------------------------------------------- ;

%macro l1_variable;

​

  %if &do_partitions and not %eval(&tabid in &tabid_exc)

    %then %let pn=1 ;  /* use 1st partition as proxy for all partition */

    %else %let pn= ;

  %* Collect table meta data - size, contents, total observations ;

  proc contents data=qadata.&&&tabid.table.&pn. out=l1_cont_temp noprint;

  run;

​

  %table_size (libin=QADATA, dsin=&&&tabid.table, libout=work, dsout=l1_size_temp);

​

  data dplocal.l1_cont_temp;

    length TABID $3 MEMNAME $32;

    set l1_cont_temp(rename=(memname=t_memname));

    tabid=upcase("&tabid.");

    memname=PRXCHANGE('s/\d+$//', 1, trim(upcase(t_memname))) ;

    drop t_memname ;

  run;

​

  data dplocal.l1_cont_&tabid.;

    merge dplocal.l1_cont_temp l1_size_temp;

    by tabid memname;

  run;

​

  proc sql noprint;

    drop table dplocal.l1_cont_temp, l1_size_temp

    ;

  quit;

​

​

  %* Merge meta data to model l1 compliance lookup;

  proc sql noprint;

    create table dplocal.l1_scdm_comp_&tabid. as

    select upcase("&tabid.") as TabID length=3

         , coalesce (a.variable,b.name) as var label="Variable Name"

         , a.varid label="SCDM Variable ID"

         , case when a.varid ne " " then "Y"

                else "N"

           end as MS_var label="Variable expected?"

         , case when length=. then "N"

                else "Y"

           end as DP_var label="Variable present?"

         , a.vartype as MS_type label="Expected variable type"

         , case when b.type=2 then 'C'

                when b.type=1 then 'N'

                else ' '

           end as DP_type label="Actual variable type" length=1

         , a.varlength as MS_length label="Expected variable length" length=3

         , b.length as DP_length label="Actual variable length" length=3

         , b.formatl as format_length label="Actual FORMATL value, if present" length=3

         , . as req_length label="Required variable length" length=3

    from infolder.lkp_all_l1 (where=(lowcase(tabid)=lowcase("&tabid."))) as a

      full join dplocal.l1_cont_&tabid. (keep=name type length formatl nobs) b

      on upcase(a.variable)=upcase(b.name)

    order by a.varid

    ;

  quit;

​

​

  %* Run query to collect table variable-value level counts;

    %do_l1_query ;;

​

  %* update metadata with required length result ;